PDF Drucker als Druckerfreigabe + Passwort

[Weltalltrauma 15]

Moin Moin allerseits,

 

ich stehe vor der kleinen Aufgabe einen PDF Printer auf einem 2008 R2 als Druckerfreigabe einzurichten. Die PDF sollen nach dem Druck automatisch in einen Share gelegt werden, zusätzlich sollen die PDFs ein paar Sicherheitsfeatures haben, wie "Passwort, nicht veränderbar, keinen Text kopieren usw".

 

Mit dem PDFCreator 1.7.3 habe ich es als Druckerfreigabe hinbekommen, dass er druckt und in die richtige Druckerfreigabe die PDFs erstellt. Allerdings scheitert es an den Sicherheitsfeatures, welche partout nicht übernommen werden wollen. Nach rumprobieren, bin ich auf einen Blogeintrag gestoßen, welcher das Problem beschreibt und man muss das ganze in die Registriy manuell eintragen. Funktioniert leider nicht wirklich. Möglicherweise liegt es an einem Versionsunterschied, zwischen Blog und meiner Version. Morgen teste ich es mit der Version aus dem Blog.

 

Mir qualmt gerade gewaltig der Kopf und ich wollte mich nach einem anderen Programm ( möglichst Open Source bzw. günstig )erkundigen, so dass ich vielleicht um den PDFCreator rumkomme. Vielleicht habt ihr ja einen Ratschlag oder Tipp.

 

Grüße

[Sanches 22]

Moin,

 

prüfe einfach mal, ob ggf. qvPDF eine Alternative wäre.

https://sourceforge.net/projects/qvpdf/

 

Gruß Sebastian

[monstermania 53]

Hmm,

evtl. mal den PDF24 Creator probiert. Der sollte das m.W. nach auch können.

https://de.pdf24.org/creator.html

 

Ansonsten ist beim PDFCreator ja irgendwas mit Version 2.X aktuell.

 

Gruß

Dirk

[Sunny61 773]

Ansonsten ist beim PDFCreator ja irgendwas mit Version 2.X aktuell.

Ab der Version 2 ist vieles nicht mehr vorhanden, was es in der 1.73 noch gibt, wie z.b. die Serverinstallation.

[Weltalltrauma 15]

Hmm,

evtl. mal den PDF24 Creator probiert. Der sollte das m.W. nach auch können.

https://de.pdf24.org/creator.html

 

Ansonsten ist beim PDFCreator ja irgendwas mit Version 2.X aktuell.

 

Gruß

Dirk

 

PDF24 bin ich gerade am testen, sieht auf den ersten Blick sieht es gut aus. Ich kämpfe allerdings gerade mit den Berechtigungen, wenn ich mit meinem User über die Freigabe drucken möchte, bringt der Druckjob eine Fehlermeldung. Mit meinem Adminaccount funktioniert es.

 

Beim PDF Creator hat sich mit der 2.x Version leider so einiges verändert, wie Sunny schon geschrieben hat eben auch die Serverinstallation. Für die Businessvariante möchten sie jetzt Geld verdienen.

 

Derzeit bekomme ich es mit dem PDFCreator 1.7.3 hin, dass die PDF automatisch in ein Verzeichnis gespeichert werden, zusätzlich versieht PDF Creator per verschiedenen VBS Scripte entweder mit einem Briefkopf oder mit einem Passwort.  Ich müsste die beiden VBS Scripte zu einem fassen, damit die PDF mit Briefkopf+Passwort versehen wird. Allerdings sind VBS Scripte nicht wirklich meine Stärke.

 

qvPDF: War leider keine Alternative. Bei der Installation sind mir nur so die Fehlermeldungen entgegen gesprungen.

[zahni 525]

Ich kann hier ein kommerzielles Produkt empfehlen:

https://www.pdf-tools.com/pdf/pdf-printer-pdfa-drucken.aspx

Eventuell auch eines der anderen Produkte. Muss Du Dir anschauen.

Wir nutzen für eine bestimmte Lösung den PDF-Printer:  https://www.pdf-tools.com/pdf/pdf-printer-pdfa-drucken.aspx

[Sunny61 773]

Derzeit bekomme ich es mit dem PDFCreator 1.7.3 hin, dass die PDF automatisch in ein Verzeichnis gespeichert werden, zusätzlich versieht PDF Creator per verschiedenen VBS Scripte entweder mit einem Briefkopf oder mit einem Passwort.  Ich müsste die beiden VBS Scripte zu einem fassen, damit die PDF mit Briefkopf+Passwort versehen wird. Allerdings sind VBS Scripte nicht wirklich meine Stärke.

Kannst Du die Scripte hier veröffentlichen? Evtl. kriegt man es ja hin.

 

Alternativ mit Hilfe von VB.Net und der DLL von Aspose das ganze machen.

[Weltalltrauma 15]

Vielen Dank für das Feedback:

 

Zahni: Die Software macht einen guten Eindruck, ist vorgemerkt wenn es auf eine Businesslösung hinauslaufen wird.

 

@Sunny61:

 

Klar nur zu gerne.

 

Für den Briefkopf

' AddWatermarkToPDF script

' Part of PDFCreator

' License: GPL

' Homepage: http://www.sf.net/projects/pdfcreator

' Version: 1.1.0.0

' Date: September, 1. 2005

' Author: Frank Heindörfer

' Comments: This script needs pdftk.

'           For more informations about the freeware pdftk use this link:

'           http://www.accesspdf.com



Option Explicit



Const AppTitle = "PDFCreator - AddWatermarkToPDF"

Const PathToPdftk = "C:\PDFtk\bin\pdftk.exe"

Const WatermarkPDF = "C:\PDFtk\Briefpapier.pdf"



Dim objArgs, fname, tfname, fso, WshShell, oExec



Set objArgs = WScript.Arguments



If objArgs.Count = 0 Then

 MsgBox "This script needs a parameter!", vbExclamation, AppTitle

 WScript.Quit

End If



fname = objArgs(0)



Set fso = CreateObject("Scripting.FileSystemObject")



If Ucase(fso.GetExtensionName(fname)) <> "PDF" Then

 MsgBox "This script works only with pdf files!", vbExclamation, AppTitle

 WScript.Quit

End If



If Not fso.FileExists(PathToPdftk) Then

 MsgBox "You need pdftk for this script!" & vbcrlf & vbcrlf & _

  "Please go to http://www.accesspdf.com and download it.", vbExclamation, AppTitle

 WScript.Quit

End If



If Not fso.FileExists(WatermarkPDF) Then

 MsgBox "Can't find the watermark pdf file!", vbExclamation, AppTitle

 WScript.Quit

End If



Set WshShell = CreateObject("WScript.Shell")



tfname = fso.GetTempName

WshShell.Run PathToPdftk & " """ & fname & """ background " & WatermarkPDF & " output """ & tfname & """",0,true



If Not fso.FileExists(tfname) Then

 MsgBox "There was an error using ""pdftk""!", vbCritical, AppTitle

 WScript.Quit

End If



If fso.FileExists(fname) Then

 fso.DeleteFile(fname)

End If



fso.MoveFile tfname, fname

Für die Verschlüsselung:

' EncryptAES128 script

' Part of PDFCreator

' License: GPL

' Homepage: http://www.sf.net/projects/pdfcreator

' Version: 1.0.0.0

' Date: September, 23. 2010

' Author: Frank Heindörfer

' Comments: Encrypt a pdf file with the aes methode.



Option Explicit



Const AppTitle = "EncryptAES128"



Dim objArgs, fname, tfname, fso, WshShell, oExec, pdf, enc



Set objArgs = WScript.Arguments



If objArgs.Count = 0 Then

 MsgBox "This script needs a parameter!", vbExclamation, AppTitle

 WScript.Quit

End If



fname = objArgs(0)



Set fso = CreateObject("Scripting.FileSystemObject")



If Ucase(fso.GetExtensionName(fname)) <> "PDF" Then

 MsgBox "This script works only with pdf files!", vbExclamation, AppTitle

 WScript.Quit

End If



tfname = fso.GetTempName



Set WshShell = CreateObject("WScript.Shell")



Set enc = WScript.CreateObject("pdfforge.PDF.PDFEncryptor")

enc.AllowAssembly = false

enc.AllowCopy = false

enc.AllowFillIn = true

enc.AllowModifyAnnotations = false

enc.AllowModifyContents = false

enc.AllowPrinting = true

enc.AllowPrintingHighResolution = false

enc.AllowScreenreaders = false

enc.OwnerPassword = "pdfforge"

Set pdf = WScript.CreateObject("pdfforge.pdf.pdf")



pdf.EncryptPDFFile fname, tfname, (enc)



If Not fso.FileExists(tfname) Then

 MsgBox "There was an error during enrypting!", vbCritical, AppTitle

 WScript.Quit

End If



If fso.FileExists(fname) Then

 fso.DeleteFile(fname)

End If



fso.MoveFile tfname, fname



Set enc = Nothing

Set pdf = Nothing

Set fso = Nothing

Set WshShell = Nothing

Set objArgs = Nothing

[Sunny61 773]

Alle beide Script in eines packen, dürfte nicht schwer sein. Ich würde es hier dazwischen packen:

 

If Not fso.FileExists(tfname) Then

 MsgBox "There was an error using ""pdftk""!", vbCritical, AppTitle

 WScript.Quit

End If

*******************
Hier den Inhalt des zweiten Scriptes einfügen!
*******************

If fso.FileExists(fname) Then

 fso.DeleteFile(fname)

End If

Alternativ packst Du den Aufruf von beiden Scripten in ein Script. Das kann so aussehen:

 

Dim WshShell
Set WshShell = CreateObject("WScript.Shell")

WshShell.Run "wscript.exe C:\DeinZweites Script.vbs" , 1, True

Und das ganze dann eben mit zwei Scripten.