vbscript zum anlegen von Benutzer in eine AD

[whatzzup 0]

Hallo Zusammen,

 

ich bin seit kurzem auf der Suche nach einem Script das es ermöglicht  User via Textdokument oder Exceltabelle anzulegen. Ich bin auf meiner Suche auf das Script von Marka gestoßen und finde es auch sehr gut abgesehen davon, dass es meine Textdatei zum einlesen nicht findet.

 

 

 

 

' © 2005 by Markus Kafurke, www.marka-it.net
 
msg = "Kurzbeschreibung:" & vbCr & "Dieses Skript legt automatisiert neue Konten an und liest die dafür nötigen Angaben aus einer userliste ." & vbCr & vbCr & "Skript jetzt ausführen?"
antwort = MsgBox(msg, vbYesNo + vbQuestion)
if antwort = vbNo then
  MsgBox "Abbruch", vbExclamation
  WScript.Quit
end if
protokoll = "c:\protokoll.txt"
' Das WScript.Network-Objekt liefert den Namen des Computers,
' der als Vorgabe angeboten wird
'SYS: Windows Script Host Runtime Library
Set net = CreateObject("WScript.Network")
ComputerName = InputBox("Bitte geben Sie den Computernamen ein!",,net.ComputerName)
On Error Resume Next
Set computer = GetObject("WinNT://" & ComputerName & ",computer")
If Err.number = 0 Then
   MsgBox "Verbindung hergestellt."
Else
   MsgBox "Keine Verbindung zu " & ComputerName
   WScript.Quit
End If
On Error Goto 0
dateiname = InputBox("Wo liegen die Kontoinformationen?",," ")
' Datei öffnen
'SYS: Microsoft ® Script Runtime
Set fs = CreateObject("Scripting.FileSystemObject")
If Not fs.FileExists(dateiname) Then
   MsgBox "Die Datei existiert am angegebenen Ort nicht!"
   WScript.Quit
End If
Set infos = fs.OpenTextFile(dateiname)
' Protokolldatei öffnen
Set output = fs.CreateTextFile(protokoll, True)
' Datei zeilenweise bis zum Ende (atEndOfStream) lesen:
Do Until infos.AtEndOfStream
   ' eine Zeile einlesen
   zeile = infos.ReadLine
  
   ' Informationen durch Semikola splitten
   details = Split(zeile, ";")
  
   ' Konto anlegen
   Set kontoneu = computer.Create("User", Trim(details(0)))
   kontoneu.SetPassword Trim(details(1))
   kontoneu.Description = Trim(details(2))
   On Error Resume Next
   kontoneu.SetInfo
   If Err.number = 0 Then
      WriteLog details(0) & " angelegt."
      AddToGroup Trim(details(3)), kontoneu.ADsPath
   Else
      WriteLog details(0) & " konnte nicht angelegt werden!"
   End If
   Err.Clear
   On Error Goto 0
Loop
' Dateien schließen
infos.Close
output.Close
' Protokoll anzeigen:
'SYS: Microsoft ® Script Runtime
Set wshshell = CreateObject("WScript.Shell")
wshshell.Run """" & protokoll & """"

Sub AddToGroup(gruppenname, kontoname)
   On Error Resume Next
   Set gruppe = GetObject("WinNT://" & ComputerName & "/" & gruppenname & ",group")
   gruppe.Add kontoname
   gruppe.SetInfo
   If Err.number = 0 Then
      WriteLog "Konto ist Mitglied in Gruppe " & gruppenname
   Else
      WriteLog "Konto konnte nicht zum Mitglied in Gruppe " & gruppenname & " gemacht werden."
   End If
   Err.Clear
End Sub
Sub WriteLog(text)
   ' eine Zeile ins Protokoll schreiben
   output.WriteLine text
End Sub

 

 

Ich bin mir recht sicher das die Datei im von mir angegebenen Pfad ist nur bekomme ich immer das die Datei am angegebenen Ort nicht existiert.

 

Ich danke schon mal im Vorraus für die Hilfe

 

Gruß

bearbeitet 6. März 2013 von whatzzup

[Sunny61 773]

Dann ersetzt die Inputbox durch einen harten Pfad:

dateiname = "C:\Hier_liegt_die_Textdatei.txt"

[whatzzup 0]

hi,

 

hab ich gemacht nur das Problem bleibt bestehen

[Sunny61 773]

Hat die Datei denn Leerzeichen? Oder gibt es im Pfad ein Leerzeichen?

[whatzzup 0]

nein keins von beiden hat ein leerzeichen

ah das Problem mit dem Finden der Datei habe ich jetzt. Ich hab nich an die Dateiendung gedacht nun habe ich das Problem das die Konten nicht angelegt werden können

[Sunny61 773]

nun habe ich das Problem das die Konten nicht angelegt werden können

 

 

Bei der Fehlermeldung wird es schwer einen Lösungsvorschlag zu posten.

 

 

EDIT: Vielleicht hilft dir bei der Lösung insgesamt ja dieser Artikel: http://www.faq-o-matic.net/2008/01/19/excel-admins-unbekannter-liebling/

bearbeitet 6. März 2013 von Sunny61

[whatzzup 0]

Hey,

 

jetzt läuft alles wie es sein sollen. Die Konten wurde nämlich schon angelegt bei einem früheren Versuch wurde nur nicht im schon geöffneten Server-Manager nicht angezeigt.

 

trotzdem vielen dank für die Hilfe

[NorbertFe 1.845]

Das hätte man sicher anhand einer "GENAUEN" Fehlermeldung relativ schnell erkennen können. ;)

[Sunny61 773]

Die Konten wurde nämlich schon angelegt bei einem früheren Versuch wurde nur nicht im schon geöffneten Server-Manager nicht angezeigt.

 

trotzdem vielen dank für die Hilfe

 

Deshalb ist F5 die Taste die man häufiger drücken sollte, aber natürlich muß auch Links der richtige Baum markiert sein. ;)

 

Freut mich für Dich und Danke für die Rückmeldung. ;)