Wsus update handling

Salgermi · 24. Juli 2006

Hi,

ich habe nun den Wsus auf einem unser Server installiert, das GPO erstellt und probiere

jetzt mit einem Testclient. Die GP für die Updateinstallation ist auf Punkt 4 eingestellt,

so daß Updates automatisch geladen, aber erst zu einem Festen Zeitpuknt installiert werden.

Nu folgendes:

Es ist ziemlich stöhrend, daß die Updates bei ausgeschalteten Clients direkt beim nächsten

Start installiert werden, denn wenn die Mitarbeiter morgens kommen, wollen die Arbeiten

und nicht auf Updates warten und Däumchen drehen.

Ist es möglich, Punkt 3 so zu konfigurieren, daß die Updates geladen und beim Herunterfahren

des Clients erzwungenermassen installiert werden, ohne Nachfrage und Möglichkeit,

die UPdates nicht zu installieren? Der Haken ist, die Mitarbeiter sind ALLE lokale Admins

da sonst eine Software nicht funktioniert.

Gadget · 28. Juli 2006

Hi Salgermi,

das reiht sich leider in die lange WSUS-Wunschliste ein... wäre auch meine bevorzugte Lösung.

"Force install Updates @ Shutdown"

Hier ist es schon unter Punkt 42 erwähnt.

http://wsuswiki.com/WishList

LG Gadget

Renator · 28. Juli 2006

Nunja, wenn es dir wichtig ist, dann könntest du via wakeonLAN die Clients in der Nacht wecken und dann per Script oder DameWare Utilities etc. wieder herunterfahren lassen. So werden dann deine Mitarbeiter überhaupt nicht mehr gestöhrt und die Updates sind VOR der Arbeit mit dem Computer installiert!

thorgood · 28. Juli 2006

Hi,

"Force install Updates @ Shutdown" ist aber kein Problem selbst zu bauen.

Über Shutdown Scripts eine kleines VB Script ausführen.

Dieses fragt über die Windows Update Agent API nach aktuellen Patches,

downloaded und installiert diese beim herunterfahren.

Der Dienst Automatische Updates kann dabei sogar auf manuell stehen,

so "belästigt" er tagsüber lokalen Administratoren nicht.

Wer Fragen hat fragt.

ixus55fan · 28. Juli 2006

Über Shutdown Scripts eine kleines VB Script ausführen.

Dieses fragt über die Windows Update Agent API nach aktuellen Patches,

downloaded und installiert diese beim herunterfahren..

Warum postest Du das kleine VB-Script nicht einfach?

thorgood · 28. Juli 2006

Weil ich mich bei der Wärme nur ungern bewege :D

1. Ein Shutdown Script anlegen

Scriptname: %windir%\system32\wscript.exe

Scriptparameter: //B //NoLogo %windir%\system32\wuau.vbs

2. Script wuau.vbs im System32 erstellen:

Set updateSession = CreateObject("Microsoft.Update.Session")
Set updateSearcher = updateSession.CreateupdateSearcher()
Set searchResult = updateSearcher.Search("IsInstalled=0 and Type='Software'")

If searchResult.Updates.Count = 0 Then
WScript.Quit
End If

Set updatesToDownload = CreateObject("Microsoft.Update.UpdateColl")

For I = 0 to searchResult.Updates.Count-1
   Set update = searchResult.Updates.Item(I)
   updatesToDownload.Add(update)
Next

Set downloader = updateSession.CreateUpdateDownloader() 
downloader.Updates = updatesToDownload
downloader.Download()

Set updatesToInstall = CreateObject("Microsoft.Update.UpdateColl")

For I = 0 To searchResult.Updates.Count-1
   set update = searchResult.Updates.Item(I)
   If update.IsDownloaded = true Then
      updatesToInstall.Add(update)	
   End If
Next

Set installer = updateSession.CreateUpdateInstaller()
installer.Updates = updatesToInstall
Set installationResult = installer.Install()

WScript.Quit

Wer für den Anwender noch eine kleines Hinweisfenster haben möchte, fügt vor

Set updatesToDownload = CreateObject("Microsoft.Update.UpdateColl")

noch folgende Zeilen ein

Set wshShell = WScript.CreateObject("WScript.Shell")

wshShell.Run "%windir%\system32\wuau.hta", 0, False

und erstellt im System32 die Datei wuau.hta

<html>
<head>
<title>Windows Update</title>
<HTA:APPLICATION
CONTEXTMENU="no"
INNERBORDER="no"
MAXIMIZEBUTTON="no"
MINIMIZEBUTTON="no"
NAVIGABLE="no"
SYSMENU="no"
SCROLL="no">
</head>
<body bgcolor=buttonface style="font-family:Arial">
<center><font size=-1>Installiere Updates ...</size></center>
</body>
</html>
<script language="VBScript">
 Sub Window_Onload
     self.Focus()
     self.ResizeTo 1,1
     self.MoveTo (screen.width-300)/2,(screen.height-80)/2
     self.ResizeTo 300,80
 End Sub
</script>

Die HTA könnt ihr in Farbe, Form und Text beliebig anpassen.

Puh, geschafft. Erstmal ausruhen. :cool:

/edit: Die maximale Wartezeit für GP Scripts natürlich auf 0 (unendlich) stellen. /

Anmelden

Wsus update handling

Empfohlene Beiträge

Salgermi 10

Gadget 37

Renator 10

thorgood 10

ixus55fan 10

thorgood 10

Erstelle ein Benutzerkonto oder melde dich an, um zu kommentieren

Benutzerkonto erstellen

Anmelden

Menu

Aktivitäten