Skripte

[bind_maik 10]

hi zusammen!

 

weiss jemand wie ich remote server per skript rebooten kann & dienste neu starten kann?

mit welcher skript sprache oder programmiersprache ist dies am einfachsten zu bewältigen?

 

danke

[thorgood 10]

Hallo bind_maik,

 

VBScript mit WMI bietet sich da an.

 

reboot.vbs

strComputer = "server-name"

Set objWMIService = GetObject("winmgmts:" _
   & "{impersonationLevel=impersonate,(Shutdown)}!\\" & strComputer & "\root\cimv2")

Set colOperatingSystems = objWMIService.ExecQuery _
   ("Select * from Win32_OperatingSystem")

For Each objOperatingSystem in colOperatingSystems
   ObjOperatingSystem.Reboot()
Next

service_start.vbs

strComputer = "server-name"
strService  = "service-name"

Set objWMIService = GetObject("winmgmts:" _
   & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")

Set colServiceList = objWMIService.ExecQuery _
       ("Select * from Win32_Service where Name='" & strService & "'")

For each objService in colServiceList
   errReturn = objService.StartService()
Next

service_stop.vbs

strComputer = "server-name"
strService  = "service-name"

Set objWMIService = GetObject("winmgmts:" _
   & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")

Set colServiceList = objWMIService.ExecQuery _
       ("Select * from Win32_Service where Name='" & strService & "'")

For each objService in colServiceList
   errReturn = objService.StopService()
Next

thorgood