Ereignissabonement für 2008 konfigurieren

[Orphobia 10]

Hallo,

 

kann mir jmd sagen wo ich eine *.bat Datei herbekomme, die im eventlog ein ereigniss generiert,

so das ich das ereignisabo auch testen kann?!

 

bin für jede Info verbunden

[NilsK 3.011]

Moin,

 

ich habe dafür mal ein VBS-Skript gebaut:

 

Ereigniserzeuger.vbs

Set objShell = CreateObject("WScript.Shell")
intMinIntervall = 60
Dim arrTyp(2,1)
arrTyp(0, 0) = 1
arrTyp(0, 1) = "Fehler"
arrTyp(1, 0) = 2
arrTyp(1, 1) = "Warnung"
arrTyp(2, 0) = 4
arrTyp(2, 1) = "Information"

Dim arrMeldung(3)
arrMeldung(0) = "Ein ernsthaftes Ereignis ist aufgetreten."
arrMeldung(1) = "Es gab ein ungewöhnliches Vorkommnis."
arrMeldung(2) = "Das verstehe ich gar nicht."
arrMeldung(3) = "Bitte weitergehen, es gibt nichts zu sehen!"

Randomize
While 1 = 1
intMeldung = Int((3 - 0 + 1) * Rnd(1) + 0)
intTyp = Int((2 - 0 + 1) * Rnd(1) + 0)
intWarten = Int((2 - 1 + 1) * (Rnd(1) + 1) * intMinIntervall) 
objShell.LogEvent arrTyp(intTyp, 0), arrTyp(intTyp, 1) & " - Ereigniserzeuger: " & arrMeldung(intMeldung) _
	& " Nächstes Ereignis in " & intWarten & " Sekunden."
WScript.Echo Now & " " & arrTyp(intTyp, 1) & " - Ereigniserzeuger: " & arrMeldung(intMeldung) _
	& " Nächstes Ereignis in " & intWarten & " Sekunden."
WScript.Sleep(intWarten * 1000)
Wend

 

Das Skript erzeugt in zufälligen Abständen zwischen 1 und 60 Sekunden Ereignisse verschiedener Schweregrade im Application Log. Aufruf mit cscript:

 

cscript c:\pfad\Ereigniserzeuger.vbs

 

Gruß, Nils

[Orphobia 10]

Hallo Nils

 

besten dank für die schnelle Hilfe