Netzwerkdrucler per vb Script löschen

[KLDAH 10]

Hallo,

 

ich habe einen Script, der Drucker abhängig von der AD-Gruppe mappt:

 

____________________________________________________________

strUser = "LDAP://" & CreateObject("ADSystemInfo").UserName

StrPrintSRV = "Printserver"

 

On Error resume next

 

rem Drucker mappen, wenn Benutzer in Gruppe "Kevin_Drucker"

If GetObject("LDAP://CN=Kevin_Drucker,OU=Gruppen,DC=Domain,DC=de").IsMember(strUser) Then

Set WshNetwork = Wscript.CreateObject("Wscript.Network")

WshNetwork.AddWindowsPrinterConnection "\\" & strPrintSRV & "\Drucker1"

WshNetwork.AddWindowsPrinterConnection "\\" & strPrintSRV & "\Drucker2"

WshNetwork.AddWindowsPrinterConnection "\\" & strPrintSRV & "\Drucker3"

end if

____________________________________________________________

 

Ich möchte gerne vorher alle Drucker, die verbunden sind löschen.

Wie kann ich das per Script machen?

 

Danke schonmal.

 

Gruß

 

Kevin

[phoenixcp 10]

In diesem Fall müsstest du die Methode RemovePrinterConnection der Klasse Network verwenden.

Beispiel:

WshNetwork.RemovePrinterConnection "\\" & strPrintSRV & "\Drucker1"
[/Code]

 

Gruß

Carsten

[KLDAH 10]

Danke für die Antwort.

Ich möchte aber alle Drucker löschen, die drin sind. Es könnte ja sein, dass noch andere Drucker da sind. Gibt es da einen Befehl?

Ist das möglich?

[phoenixcp 10]

Das könnte man zum Beispiel so lösen:

Const NETWORK = 22

Set objNetwork = CreateObject("WScript.Network")

strComputer = "."

Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
Set colPrinters = objWMIService.ExecQuery("Select * From Win32_Printer")

For Each objPrinter in colPrinters
    If objPrinter.Attributes And NETWORK Then 
        strPrinter = objPrinter.Name
        objNetwork.RemovePrinterConnection strPrinter
    End If
Next

[/Code]

 

Quelle: Hey, Scripting Guy! How Can I Remove All the Network Printers on a Computer?

[KLDAH 10]

Danke!

 

für was ist die const=22?

 

was muss ich für strcomputer einsetzen

[phoenixcp 10]

Network steht in diesem Fall für ein konstantes Flag, welches einen Netzwerkdrucker kennzeichnet. strcomputer ist schon mit "." vorbelegt, was dem lokalen Rechner entspricht. Auf diesem wird dein Anmeldeskript ja auch ausgeführt, von daher passt das.

[KLDAH 10]

Funktioniert nicht.

 

Ich bekomme immer die Meldung: Diese Netzwerkverbindung ist nicht vorhanden.

 

Muss ich daran noch was anpassen?

[phoenixcp 10]

Soweit ich das überblicke musst du daran nix anpassen. Bekommst du denn überhaupt Drucker aus der WMI-Query zurück? Bau dir doch mal eine MsgBox in die ForEach-Schleife ein, welche dir den grade bearbeiteten Drucker anzeigt.

[KLDAH 10]

das funktioniert auch schon nicht.

 

Kannst du nochmal drüberschauen?

Ich bin nicht so fit in vb?

[phoenixcp 10]

Dann versuch dich mal mit Messageboxen ala "jetzt bin ich hier und hier" an die Stelle des Problems ranzudebuggen und schau mal, wo das Skript aussteigt.

 

Hast du an dem Skript nochwas modifiziert?

[KLDAH 10]

ne, hab versucht es genau so aufzurufen

[phoenixcp 10]

Und ist aktuell überhaupt ein Netzwerkdrucker verbunden?

[KLDAH 10]

ja klar

[phoenixcp 10]

Dann probier es mal so:

Set objNetwork = CreateObject("WScript.Network")

strComputer = "."

Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
Set colPrinters = objWMIService.ExecQuery("Select * From Win32_Printer")

For Each objPrinter in colPrinters
    If objPrinter.Attributes Then 
        strPrinter = objPrinter.Name
        objNetwork.RemovePrinterConnection strPrinter
    End If
Next
[/Code]

 

BTW: Wir reden von einem XP-Client?

[KLDAH 10]

damit funktioniert es:

 

strComputer = "."

 

Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")

 

Set colInstalledPrinters = objWMIService.ExecQuery _

("Select * From Win32_Printer Where Network = True")

 

For Each objPrinter in colInstalledPrinters

objPrinter.Delete_

Next