WMI Script - ADS Canonical Name

[Apex 15]

Hallo

 

ich versuche mir über ein Skript den canonicalName und einige andere Attribute ausgeben zu lassen.

 

Dazu verwende ich folgendes Skript

Const ADS_SCOPE_SUBTREE = 2

Set objConnection = CreateObject("ADODB.Connection")
Set objCommand =   CreateObject("ADODB.Command")
objConnection.Provider = "ADsDSOObject"
objConnection.Open "Active Directory Provider"

Set objCommand.ActiveConnection = objConnection
objCommand.CommandText = _
   "Select Name, Location, canonicalName, operatingSystemVersion from " & _
       "'LDAP://DC=fabrikam,DC=com' where objectClass='computer'" & _
           " and operatingSystemVersion = '5.1 (3600)'"  
objCommand.Properties("Page Size") = 1000
objCommand.Properties("Searchscope") = ADS_SCOPE_SUBTREE 
Set objRecordSet = objCommand.Execute
objRecordSet.MoveFirst

Do Until objRecordSet.EOF
   Wscript.Echo "Computer Name: " & objRecordSet.Fields("Name").Value
   Wscript.Echo "Location: " & objRecordSet.Fields("Location").Value
   Wscript.Echo "canonicalName: " & objRecordSet.Fields("canonicalName").Value
   objRecordSet.MoveNext
Loop

Das habe ich hier gefunde: Active Directory Computer Account VBScript Scripts

 

Leider funktioniert ein Wscript.Echo nicht mit dem Attribut canonicalName... Warum?

 

"Provider: Die Tabelle ist nicht vorhanden" ?

 

Wenn ich mir das mit ADSIedit ansehe ist es auch nur ein Unicode String wie jedes andere...?

[Theo Dor 10]

Ich glaube, das Attribut (Feld) heißt einfach nur "cn".

[Apex 15]

Hallo,

 

den Common Name (cn) ist dem Name gleichzusetzen, mich interessiert wirklich der canonicalName.

 

Momentan behelfe ich mir mit dem DN (distinguishedName), wer Hinweise hat, warum es nicht mit dem canonicalName geht...?

[thorgood 10]

Hi,

 

canonicalName ist ein Array.

Wscript.Echo "canonicalName: " & Join(objRecordSet.Fields("canonicalName").Value)

 

thorgood

[Apex 15]

Danke :)

 

Ich bin begeistert, nach langem Suchen im Netz endlich die Lösung hier gefunden zu haben. :)