2 Objektklassen im AD per vbs abfragen

[morpheus 10]

irgendwie bekomme ich das nicht so richtig hin.

[phoenixcp 10]

Was hast denn bist jetzt probiert?

[morpheus 10]

naja ... das script sieht immer noch so aus: wo wie muss die string-array funktion denn eingebaut werden?

 

Const ADS_SCOPE_SUBTREE = 2

Set fso=CreateObject("Scripting.FileSystemObject")

Set tf=fso.OpenTextFile("SSOWatch.txt",2,1)

Set objConnection = CreateObject("ADODB.Connection")

Set objCommand = CreateObject("ADODB.Command")

objConnection.Provider = "ADsDSOObject"

objConnection.Open "Active Directory Provider"

 

Set objCommand.ActiveConnection = objConnection

objCommand.CommandText = _

"Select distinguishedName from " & _

"'LDAP://DC=test,DC=de' where objectClass='enatelSoftwareModule'" & _

" and enatelSoftwareModuleVersion = '72623751'"

objCommand.Properties("Page Size") = 1000

objCommand.Properties("Searchscope") = ADS_SCOPE_SUBTREE

Set objRecordSet = objCommand.Execute

objRecordSet.MoveFirst

 

Do Until objRecordSet.EOF

tf.Writeline objRecordSet.Fields("distinguishedName").Value

objRecordSet.MoveNext

Loop

[phoenixcp 10]

Probier mal so:

 

Const ADS_SCOPE_SUBTREE = 2
Set fso=CreateObject("Scripting.FileSystemObject")
Set tf=fso.OpenTextFile("SSOWatch.txt",2,1)
Set objConnection = CreateObject("ADODB.Connection")
Set objCommand = CreateObject("ADODB.Command")
objConnection.Provider = "ADsDSOObject"
objConnection.Open "Active Directory Provider"

Set objCommand.ActiveConnection = objConnection
objCommand.CommandText = _
"Select distinguishedName from " & _
"'LDAP://DC=test,DC=de' where objectClass='enatelSoftwareModule'" & _
" and enatelSoftwareModuleVersion = '72623751'"
objCommand.Properties("Page Size") = 1000
objCommand.Properties("Searchscope") = ADS_SCOPE_SUBTREE
Set objRecordSet = objCommand.Execute
objRecordSet.MoveFirst

Do Until objRecordSet.EOF
'tf.Writeline objRecordSet.Fields("distinguishedName").Value
myDN = objRecordSet.Fields("distinguishedName").Value
myDNSplitted = Split(myDN, ",", 2)
tf.Writeline myDNSplitted(1)
objRecordSet.MoveNext
Loop

 

Würde mich auch über ne Erfolgsrückmledung freuen ;)

[morpheus 10]

Erfolg ;-) !!!

Super vielen Dank für deine Hilfe.

[phoenixcp 10]

Na bitte... der nächste Patient bitte :D