[VBS] AD-Script Problem bei Gruppenberechtigung und Namensgebung

[Todesstern 10]

Vorerst mein Script.

 

Option Explicit 

dim container 
dim gruppe1, gruppe2 
dim groupid 
dim temp1,temp2,temp3 
dim groupmaxvalue 

const domainname = "project" 
const domaintld = "dom" 
const ou = "neue Gruppen" 
const gruppenname = "TEST_P_" 
const groupname_m = "TEST_G_MITARBEITER" 
const groupname_p = "Domänen-Benutzer" 
Const ADS_GROUP_TYPE_LOCAL_GROUP = &h4 
Const ADS_GROUP_TYPE_SECURITY_ENABLED = &h80000000 

groupid = 1 
groupmaxvalue = 100 

do while groupid < groupmaxvalue 

if groupid < 10 then 
groupid = "0" & groupid 
end if 

temp1 = gruppenname & groupid & "_M" 
temp2 = gruppenname & groupid & "_P" 

Set container = GetObject("LDAP://OU=" & ou & ",DC=" & domainname & ",DC=" & domaintld) 
set gruppe1 = container.create("group", "CN= " & temp1) 
gruppe1.put "Grouptype", ADS_GROUP_TYPE_LOCAL_GROUP or ADS_GROUP_TYPE_SECURITY_ENABLED 
gruppe1.SetInfo 

Set container = GetObject("LDAP://OU=" & ou & ",DC=" & domainname & ",DC=" & domaintld) 
set gruppe2 = container.create("group", "CN= " & temp2) 
gruppe2.put "Grouptype", ADS_GROUP_TYPE_LOCAL_GROUP or ADS_GROUP_TYPE_SECURITY_ENABLED 
gruppe2.SetInfo 

groupid = groupid + 1 

loop 

Wscript.Echo("Done") 

 

soweit so gut, das funktioniert auch genau wie es soll, allerdings hab ich nun mehrere probleme:

 

in die gruppen mit der endung "_M" soll das mitglied "TEST_G_MITARBEITER" eingefügt werden.

in die gruppen mit der endung "_P" soll das mitglied "Domänen-Benutzer" eingefügt werden.

dann ganz wichtig: der prä-windows 2000 name soll immer gleich dem gruppennamen sein. momentan stehen da irgendwelche hyroglyphischen zahlenkombinationen drin.

 

das wars erstmal,

besten dank für eure hints.

[Todesstern 10]

gruppe1.Put "sAMAccountName", gruppenname & groupid & "_M"

gruppe1.putex ADS_PROPERTY_APPEND, "member", Array("CN=" & groupmember_m & ",OU=" & ou_lvl3 & ",OU=" & ou_lvl2 & ",OU=" & ou_lvl1 & ",DC=" & domainname & ",DC=" & domaintld)

 

damit hat sich das problem erledigt