Bitlocker Recovery information im AD wiederherstellen

[Thomas S 10]

Hallo zusammen,

 

vielleicht kann mir jemand diese Frage beantworten.

Wir setzen bei unseren Notebooks Bitlocker ein und speichern die Wiederherstellungskeys im AD. Soweit so gut. Jetzt haben wir ein Notebook aus der Domain herausgenommen und dessen Computerkonto gelöscht, somit ist natürlich auch der Key im AD weg. Nachdem das Notebook wieder zur Domain hinzugefügt wurde ist das Computerkonto wieder da, allerdings ohne Bitlocker Wiederherstellungskey. Welche Möglichkeiten habe ich die Bitlocker Information wieder im AD neu zu speichern?

Auf dem Notebook selbst kann ich den Key nur drucken oder in einer Datei speichern lassen. oder muss ich die Verschlüsselung entfernen und wieder neu erstellen lassen damit der Key wieder im AD erscheint?

[jarazul 10]

Das kannst du entweder manuell tun in dem du:

 

mittels

manage-bde -protectors -get c:

Zugriff auf die ID des Numerical Passwords bekommst und anschließend

 

mittels

manage-bde -protectors -adbackup c: -id "VALUE"

dies im AD speicherst.

 

Oder, falls du das automatisieren willst, ja willst du, dann nimmst du dieses Script.

 

Option Explicit

Dim strNumericalKeyID 
Dim strManageBDE,strManageBDE2 
Dim oShell 
Dim StrPath 
Dim StdOut, strCommand 
Dim Result, TPM, strLine 
Dim Flag, NumericalKeyID

Set oShell = CreateObject("WSCript.Shell")

'==================================================================================== 
'This section looks for the Bitlocker Key Numerical ID

strManageBDE = "Manage-BDE.exe -protectors -get c:" 'Bitlocker command to gather the ID

Flag = False

Set Result = oShell.Exec(strManageBDE)'sees the results and places it in Result

Set TPM = Result.StdOut    'Sets the variable TPM to the output if the strManageBDe command

While Not TPM.AtEndOfStream 
  strLine = TPM.ReadLine  'Sets strLine 
  If InStr(strLine, "Numerical Password:") Then  ' This section looks for the Numerical Password 
   Flag = True 
  End If 
  If Flag = True Then 
    If InStr(strLine, "ID:") Then  'This section looks for the ID 
     NumericalKeyID = Trim(strLine)' This section trims the empty spaces from the ID {} line 
     NumericalKeyID = Right(NumericalKeyID, Len(NumericalKeyID)-4) 
     Flag = False 'Stops the other lines from being collected 
    End If 
  End If 
Wend

strManageBDE2 = "Manage-BDE.exe -protectors -adbackup C: -ID " & NumericalKeyID 
oShell.Run strManageBDE2, 0, True 'Runs the Manage-bde command to move the numerical ID to AD.

 

How to backup recovery information in AD after BitLocker is turned ON in Windows 7 - Ask the Core Team - Site Home - TechNet Blogs

 

cheers, Daniel

[Thomas S 10]

Super danke für den Tipp und Link, Thema ist damit erledigt :)