Benutzer automatisch anlegen mit attributen(gruppe,kennwort, läuft nicht ab)

[andara 10]

Hallo Leute,

 

ich bin auf der suche nach einem script, dass automatisch lokale windows benutzer mit vorgegebenen namen, einer gruppenzugehörigkeit und anderen eigenschaften (kennwort läuft nicht ab, benutzer kann kennwort nicht aendern) erstellt.

 

Vielen Dank!

MfG andara

[blub 115]

Hallo

mit dem Boardmittel "net user" evtl. zusammen mit psexec.exe für remotezugriffe von Microsoft TechNet: Windows Sysinternals kannst du Deine Anforderung skripten

 

cu

blub

[itomix 10]

Hallo zusammen

 

vor ein paar Tagen habe ich ein ein Script das Benutzer unter Windows XP/2000/2003 anlegt programmiert hier mal ein Beispiel dazu!

 

@Info:

Das Script startet aus einer CMD (DOS) heraus, damit das Script lauffähig müsst Ihr entweder das Script über "cscript MeinScript.vbs" starten oder den Standardskripthostmit folgender Zeile als Standard definieren:

 

Syntax:

cscript //H:cscript

 

Ebenfalls nimmt das Script den Neuen Benutzer in die Gruppe "Meine Gruppe" auf. Wenn

Ihr das Script testet legt also noch eine Gruppe an oder dokumentiert den Gruppen Teil im Script aus.

 

Viel Spaß damit

Tom

 

CreateUser.vbs

 

'_________________________________________
'
' Anlegen eines Benutzer
'
' Erstellt von T. Del Greco am 25.06.2007
'_________________________________________

Const ADS_UF_PASSWD_CANT_CHANGE = &H40

strComputer = "."

WScript.StdOut.Write "Name : "
strName = WScript.StdIn.ReadLine

WScript.StdOut.Write "Passwort : "
strPwd = WScript.StdIn.ReadLine

'Beschreibung
strDesc = "Meine Benutzer"

Set objcomp = GetObject("WinNT://" & strComputer & ",computer")
Set objkonto = objcomp.Create("user", strName)

With objkonto
   .Description = strDesc
   .SetPassword strPwd
   .UserFlags = .UserFlags OR 65536
   .UserFlags = objKonto.UserFlags OR ADS_UF_PASSWD_CANT_CHANGE
   .SetInfo
End With

Set objnet = CreateObject("WScript.Network")

strComputer = objnet.ComputerName
strGruppe = "Meine Gruppe"

Set objcomp = GetObject("WinNT://" & strComputer)
Set objGruppe = objcomp.GetObject("group", strGruppe)
Set objKonto = objcomp.GetObject("user", strName)

With objGruppe
    .Add objKonto.ADsPath
    .SetInfo
End With

'_____________________________________________________________________