Jump to content

User anlegen via VBscript - Einwahl erlauben geht nicht


Der letzte Beitrag zu diesem Thema ist mehr als 180 Tage alt. Bitte erstelle einen neuen Beitrag zu Deiner Anfrage!

Empfohlene Beiträge

Vielleicht nur zur Info:

1. Ich kann auch im AD (manuell) die Einwahlberechtigung nicht auf "Zugriff über RAS Richtlinie steuern" setzen, denn der Bereich ist ausgegraut. Weshalb auch immer.

 

Weil Du in deinem ADS keinen registrierten MS RAS-Server hast, würde ich mal tippen. Konfiguriere Routing und RAS auf einem Memberserver und achte darauf das sich der Dienst im ADS registrieren kann (am besten als Domänenadmin anmelden). Dann wird der Richtlinien-Button auch verfügbar werden und dann wirst Du das Attribut auch setzen können, ob manuell oder per Script. Ferner ist RAS über Richtlinien steuern auch der Vorgabewert bei neu angelegten Nutzerobjekten.

 

'*********************************************************
' Zweck:         Setzt die RAS-Einwahlberechtigungen aller Nutzerobjekte
'                in der angegeben OU auf Richtline
' Eingaben:      keine
' Rückgabe-
' werte:         Anzahl der modifizierten Nutzerobjekte
' Ersteller:     andreas.parade@fh-jena.de 18-04-2007
'*********************************************************


On Error Resume Next

Const   ADS_SCOPE_SUBTREE = 2,_
       ADS_PROPERTY_CLEAR = 1,_
       constOU = "test" ' set name of OU here, leave blank if all

Dim fso, i, k

Set objConnection = CreateObject("ADODB.Connection")
Set objCommand =   CreateObject("ADODB.Command")
objConnection.Provider = "ADsDSOObject"
objConnection.Open "Active Directory Provider"
Set objCommand.ActiveConnection = objConnection
Set objRootDSE = GetObject("LDAP://RootDSE") 
strDNSDomain = objRootDSE.Get("DefaultNamingContext") 

WScript.Echo "Set RAS-permissions of all users in DC="&constou&","& strDNSDomain & vbcrlf & _
"This may take a while."

objCommand.Properties("Page Size") = 1000
objCommand.Properties("Searchscope") = ADS_SCOPE_SUBTREE 

objCommand.CommandText = _
   "SELECT AdsPath FROM 'LDAP://ou="&constOU&","&strDNSDomain&"' WHERE objectCategory='user'"  
Set objRecordSet = objCommand.Execute

objRecordSet.MoveFirst
i=0
k=0
Do Until objRecordSet.EOF
   strPath = objRecordSet.Fields("AdsPath").Value
   Set objUser= GetObject(strPath)
   objUser.PutEx ADS_PROPERTY_CLEAR, "msNPAllowDialin", Chr(0) 'set Value to "not set"
   objUser.SetInfo
   i=i+1
   Err.Clear
   objRecordSet.MoveNext
Loop

wscript.echo "script finished "& i &" User(s) modified "


Link zu diesem Kommentar
Der letzte Beitrag zu diesem Thema ist mehr als 180 Tage alt. Bitte erstelle einen neuen Beitrag zu Deiner Anfrage!

Schreibe einen Kommentar

Du kannst jetzt antworten und Dich später registrieren. Falls Du bereits ein Mitglied bist, logge Dich jetzt ein.

Gast
Auf dieses Thema antworten...

×   Du hast formatierten Text eingefügt.   Formatierung jetzt entfernen

  Only 75 emoji are allowed.

×   Dein Link wurde automatisch eingebettet.   Einbetten rückgängig machen und als Link darstellen

×   Dein vorheriger Inhalt wurde wiederhergestellt.   Editor-Fenster leeren

×   Du kannst Bilder nicht direkt einfügen. Lade Bilder hoch oder lade sie von einer URL.

×
×
  • Neu erstellen...