Jump to content

Doktortitel im Active Directory: Wo eintragen?


Der letzte Beitrag zu diesem Thema ist mehr als 180 Tage alt. Bitte erstelle einen neuen Beitrag zu Deiner Anfrage!

Empfohlene Beiträge

Hallo,

wir möchten das AD als Datenbasis für eine Telefonliste nehmen. Da ich im Gesundheitswesen arbeite, muss unbedingt bei den Ärzten ihr Titel (Prof., Dr., PD und was es noch so gibt) mit auf die Liste.

 

Könnte mir jemand ein Beispiel geben, wie man den Titel am besten im AD einpflegt?

 

Danke schön.

Paumus

 

P.S.: Habe schonmal ein bisschen nachgeforscht bei den Feldnamen: Active Directory: LDAP-Feldnamen - faq-o-matic.net . Das Feld Title heißt jetzt Position (wir haben Win 2003 Server) und ist daher eher für was anderes gedacht, oder?

Link zu diesem Kommentar

@phoenixcp diese feld "personalTitle" gibt es zwar theoretisch aber scheint kein standardfeld im schema zu sein. da wird man erst mal das scheme erweitern müssen denken ich um das feld zu bekommen und selbst wenn du das feld hast musst du es auch anzeigen können.

 

drs. sind da sehr merkwürdig. da soll man auch sehen wer sie sind und das auf den ersten blick :D

Link zu diesem Kommentar

Aus welchen Feldern du deinen Anzeigenamen für das Telefonbuch zusammenzimmerst, ist doch den Docs egal. Solange wie da <personalTitle> <Firstname> <LastName> oder so inder Art rauskommt, sollte denen das doch reichen.

 

Oder sollen die direkt im AD schauen, wenn sie ne Telefonnummer suchen?

 

Ich hab es so verstanden, das das AD nur die Datenbasis stellen soll und die Visualisierung dann woanders passieren soll.

 

 

Ansonsten ist das Feld (ich glaub seit Windows Server 2003) absoluter AD-Standard.

Link zu diesem Kommentar
  • 2 Monate später...

Hallo,

 

sorry erstmal, ich hab es total verplant, hier nochmal reinzugucken, da ich mich wegen meines Studiums jetzt 3 Monate nicht mehr mit dem Thema beschäftigt habe..

Vielen Dank erstmal für Eure Antworten!

 

Das Feld personalTitle sieht sehr gut aus, trifft auch genau die Anforderungen, bei Microsoft wird als Beispiel "Ms." angegeben (personaltitle Field) , also genau das Richtige ;)

 

Mein Problem ist wirklich, dass es nicht in dsa.msc auftaucht, Mist. So können das die AD-Verwalter bei uns leider nicht einpflegen. Wie kann man denn am einfachsten ein Feld pflegen, dass nicht in der ADS-Managementkonsole auftaucht? :confused:

 

 

Ich sträube mich ein bisschen dagegen, dass direkt im Anzeigenamen abzubilden, da ich das AD nur als Datenbasis verwenden will, die Telefonnummersuche soll später übers Intranet stattfinden und da würde ich den Namen gern flexibel zusammensetzen lassen (z.B. aus personalTitle, sn und givenName).

 

Vielleicht habt ihr ja noch ein paar Tipps für mich.

Danke,

paumus

Link zu diesem Kommentar

Servus,

 

Mein Problem ist wirklich, dass es nicht in dsa.msc auftaucht, Mist. So können das die AD-Verwalter bei uns leider nicht einpflegen. Wie kann man denn am einfachsten ein Feld pflegen, dass nicht in der ADS-Managementkonsole auftaucht? :confused:

 

das ist oftmals das Problem. Das die freien/nicht genutzten Attribute eben nicht in einer MMC (wie z.B. dsa.msc) angezeigt werden. Dafür müsste man dann mit C++ ran.

Und genau daran scheitert es am meisten.

 

Die einzigste "leichte" Möglichkeit, wäre üebr das Kontextmenü des Benutzers.

Aber genau dann kann man sich Fragen, für was das ganze, wenn man erst das Kontextmenü des Benutzers öffnen muss, um seinen Titel zu sehen.

 

Als Beispiel so in etwa:

Yusuf`s Directory - Blog - Personalnummer im AD eintragen

 

 

Über das Kontextmenü lässt sic hso etwas recht einfach realisieren, in einer MMC mit Aufwand der nicht unerheblich ist.

Link zu diesem Kommentar
  • 1 Monat später...

Ich habe jetzt mal die Variante über das Kontextmenü durchgespielt und stelle das hier vor, vielleicht ist es ja von allgemeinem Interesse:

 

Schritt A: Kontextmenü erweitern

Quelle: Yusuf`s Directory - Blog - Personalnummer im AD eintragen

 

kurz gefasst:

1.) adsiedit.msc

 

2.) Configuration -> DisplaySpecifiers -> 407 (dt. Sprache) -> User-Display ->

 

3.) Attribut adminContextMenu bearbeiten:

Dort sind evtl. schon Einträge vorhanden, die führende Nummer um eins erhöhen:

2, Titel setzen, C:\setpersonaltitle.vbs

 

4.) Skript an der angegebenen Stelle ablegen:

' -------------------------------------------------------------------------
' Script by Sakari Kouti (see http://www.kouti.com)
' You have a royalty-free right to use, modify, reproduce and distribute
' this script (and/or any modified version) in any way you find useful,
' provided that you agree that Addison-Wesley or Sakari Kouti has no
' warranty, obligations or liability for the script. If you modify
' the script, you must retain this copyright notice.
' -------------------------------------------------------------------------

Option Explicit
Dim wshArguments, objUser, objSchemaPersonalTitle, strCurrentTitle, strPersonalTitle, intMaxLen

On Error Resume Next

Set wshArguments = WScript.Arguments
Set objUser = GetObject(wshArguments(0))
Set objSchemaPersonalTitle = GetObject("LDAP://schema/personalTitle")

intMaxLen = objSchemaPersonalTitle.MaxRange

If objUser.personalTitle <> "" Then
   strCurrentTitle = objUser.personalTitle
Else
   strCurrentTitle = "empty"
End If

strPersonalTitle = InputBox( _
   "Aktuell eingetragener Titel: " & strCurrentTitle & vbCrLf & _
   vbCrLf & _
   "Geben Sie bitte den neuen Titel ein (1 bis " & intMaxLen & " Zeichen)", _
   Right(objUser.Name, Len(objUser.Name) - 3) & " Titel", _
   objUser.personalTitle)

If strPersonalTitle = "" Then WScript.Quit 'User clicked Cancel

If Len(strPersonalTitle) > intMaxLen Then
   MsgBox "Der neue Titel ist zu lang und wird somit nicht gespeichert.", _
       vbCritical, "Fehler"
Else
   Err.Clear
   objUser.personalTitle = strPersonalTitle
   objUser.SetInfo
   If Err Then MsgBox "Der neue Titel wird nicht gespeichert.", _
       vbCritical, "Fehler"
End If

 

Diese Einstellung wirkt auch in Taskpads.

 

 

Schritt B: Spalten anpassen

Quelle: Modifying Existing User Interfaces (Windows)

 

kurz gefasst:

 

1.) adsiedit.msc

 

2.) Configuration -> DisplaySpecifiers -> 407 -> organizationalUnit-Display

 

3.) Attribut extraColumns bearbeiten:

Es müssen die Spalten hinzugefügt werden, die man zur Auswahl haben möchte. Jeder Eintrag von extraColumns (ist ein multivalued Feld) hat folgendes Format:

company,Firma,0,150,0

LDAP-Name, So wird das Feld im Snap-In bezeichnet, 0=standardmäßig versteckt / 1= standardmäßig angezeigt, Breite in Pixeln, unbenutzt (muss 0 sein)

 

Beispiel für eine sinnvolle Konfiguration:

company,Firma,0,150,0

department,Abteilung,0,150,0

displayName,Angezeigter Name,0,100,0

givenName,Vorname,0,100,0

mail,E-Mail-Adresse,0,100,0

personalTitle,Titel,0,40,0

physicalDeliveryOfficeName,Büro,0,100,0

sn,Nachname,0,100,0

telephoneNumber,Rufnummer,0,100,0

title,Position,0,100,0

 

(Die Einträge können aus dem default-Display-Objekt, Attribut extraColumns übernommen werden. Name, Typ und Beschreibung sind immer dabei.)

post-41358-13567389466326_thumb.jpg

post-41358-13567389466506_thumb.jpg

Link zu diesem Kommentar
Der letzte Beitrag zu diesem Thema ist mehr als 180 Tage alt. Bitte erstelle einen neuen Beitrag zu Deiner Anfrage!

Schreibe einen Kommentar

Du kannst jetzt antworten und Dich später registrieren. Falls Du bereits ein Mitglied bist, logge Dich jetzt ein.

Gast
Auf dieses Thema antworten...

×   Du hast formatierten Text eingefügt.   Formatierung jetzt entfernen

  Only 75 emoji are allowed.

×   Dein Link wurde automatisch eingebettet.   Einbetten rückgängig machen und als Link darstellen

×   Dein vorheriger Inhalt wurde wiederhergestellt.   Editor-Fenster leeren

×   Du kannst Bilder nicht direkt einfügen. Lade Bilder hoch oder lade sie von einer URL.

×
×
  • Neu erstellen...